const
	fin = 'lanparty.in';
	fout = 'lanparty.out';
	maxN = 100;

var
	n, k : Integer;
	res : Integer;

	(* win[i] = Da li je Kostin tim pobedio i-tu partiju *)
	win : array[1..maxN] of Boolean;

	(*
		s[m, j] = Maksimalna razlika koja se moze ostvariti ako se prvih m
		partija podele u tacno j intervala, pri cemu intervali mogu biti i
		prazni.
	*)
	s : array[0..maxN, 0..maxN] of Integer;

	(*
		w[i, r] = Rezultat intervala koji pocinje i-tom partijom i sadrzi r
		uzastopnih partija. 1 ako pobedjuje Kostin tim, -1 ako pobedjuje
		protivnicki tim, 0 ako je nereseno.
	*)
	w : array[1..maxN, 0..maxN] of Integer;



	procedure ReadInput();
	var
		f : Text;
		i : Integer;
		ch : Char;
	begin
		Assign(f, fin);
		Reset(f);

		Readln(f, n, k);
		for i := 1 to n do
		begin
			Read(f, ch);
			win[i] := ch = 'W';
		end;

		Close(f);
	end;


	procedure WriteOutput();
	var
		f : Text;
	begin
		Assign(f, fout);
		Rewrite(f);
		Writeln(f, res);
		Close(f);
	end;


	procedure Solve();
	var
		m, i, j, l, r, t : Integer;
	begin
		for i := 1 to n do
			for r := 0 to n-i+1 do
			begin
				w[i, r] := 0;
				for l := i to i+r-1 do      (* Najpre u w[i, r] pamtimo razliku u tom intervalu. *)
					if win[l] then
						inc(w[i, r])
					else
						dec(w[i, r]);

				if w[i, r] > 0 then w[i, r] :=  1;   (* Potom korigujemo tako da w[i, r] moze da *)
				if w[i, r] < 0 then w[i, r] := -1;   (* bude samo neka od vrednosti 1, 0 ili -1. *)
			end;


		for l := 0 to k do
			s[0, l] := 0;      (* Ako nije odigrana ni jedna partija razlika u intervalima je 0. *)

		for m := 1 to n do
			s[m, 0] := -10000; (* Nije moguce podeliti vise od 0 partija na 0 intervala. *)

		for j := 1 to k do
			for m := 1 to n do
			begin
				s[m, j] := -1;     (* Najgora razlika u intervalima ne moze da bude manja od -1. *)
				for r := 0 to m do (* Poslednji interval sadrzi r partija. *)
				begin
					t := s[m-r, j-1] + w[m-r+1, r];
					if t > s[m, j] then
						s[m, j] := t;
				end;
			end;


		res := s[n, k];
	end;


begin
	ReadInput();
	Solve();
	WriteOutput();
end.
